# TCURVES.MAC
#
# Shows the standard normal curve and t-curves specified by the user.
#
# Macro is for MINITAB for Windows, release 10 and above
# Written by: Neil A. Weiss
# Date: 09/17/95
#
# Revision history:
#   04/04/00: Revised to account for changes in Release 13 for what is
#             acceptable syntax in Minitab macros.

MACRO

TCURVES

MCOLUMN C
MCONSTANT K

BRIEF 2     #DEFAULT
GPAUSE 0    #DEFAULT
NOTE
NOTE This macro shows the standard normal curve along with several t-curves
NOTE of your choice.
NOTE
NOTE How many different t-curves do you want?
SET C;
  FILE 'TERMINAL';
  NOBS 1.
COPY C K
NOTE
NOTE Enter the degrees of freedom for the t-curves.
SET C;
  FILE 'TERMINAL';
  NOBS K.
SORT C C
NOTE
NOTE NOTE: THE FIRST CURVE DRAWN WILL BE THE STANDARD NORMAL CURVE;
NOTE THEN THE T-CURVES IN INCREASING ORDER OF DEGREES OF FREEDOM.
NOTE
NOTE
CALL DRAWEM K C

ENDMACRO


MACRO

DRAWEM K C

MCOLUMN C Y.1-Y.K X Z
MCONSTANT K DF.1-DF.K I J

BRIEF 0
COPY C DF.1-DF.K
SET X
-3.5:3.5/.005
END
PDF X Z
DO I=1:K
  PDF X Y.I;
  T DF.I.
ENDDO
LAYOUT;
  WTITLE 't-curves';
  TITLE 'Standard Normal Curve and Selected t-Curves';
  FOOTNOTE 'NOTE: The black curve is the standard normal curve.'.
BRIEF 2
PLOT Z*X;
  Connect;
    Type 1;
    Color 1;
    Size 3;
  Minimum 1 -3.5;
  Maximum 1 3.5;
  Minimum 2 0;
  Maximum 2 .4;
  Axis 1;
    TFont 0;
  Axis 2;
    Type 0;
    TFont 0;
  Tick 1 -3:3;
  Tick 2;
    Type 0 1;
    TFont 0.
DO I=1:K
LET J=I+1
PLOT Y.I*X;
  Connect;
    Type 1;
    Color J;
    Size 3;
  Minimum 1 -3.5;
  Maximum 1 3.5;
  Minimum 2 0;
  Maximum 2 .4;
  Axis 1;
    TFont 0;
  Axis 2;
    Type 0;
    TFont 0;
  Tick 1 -3:3;
  Tick 2;
    Type 0 1;
    TFont 0.
ENDDO
BRIEF 0
ENDLAYOUT

BRIEF 2     #DEFAULT
GPAUSE 0    #DEFAULT
ENDMACRO