> restart;

Sample solutions for test 2

About this worksheet

Author and Date

Content, Purpose and Use

Updates and log of modifications.

Problem 1

Part a.

Parameterize the circle with center 0 and radius R:

> restart;

> zt:=R*exp(I*t);

Evaluate the integrands (including dz) along the curve

> int10:=conjugate(zt)*diff(zt,t);
int20:=1/conjugate(zt)*diff(zt,t);

Note that MAPLE does not know how to simplify this since
we did not tell that t and R are real.

> simplify(int20);

I still have not fully figured out how to work with the assume
utility -- but a workaround seems to be to use evalc -- this
apparently makes some implicit assumptions about symbols
standing for real variables.

> int1:=simplify(evalc(int10)):
int2:=simplify(convert(evalc(int20),exp)):
`1st integrand`=int1;
`2nd integrand`=int2;

integrate:

> I1:=int(int1,t=0..2*Pi);
I2:=int(int2,t=0..2*Pi);

>

Note that when assuming that t and R are real the initial simplifications
are easier -- but I recall that at some time the "assumed t" was a
different t from the one in int... -- I just don't trust assume().

> restart;
zT:=r*exp(I*T);
assume(T,real);
assume(r,real);
Int2:=1/conjugate(zT)*diff(zT,T);
int(Int2,T=a..b);
int(Int2,T=0..2*Pi);

Either way these integrals are easier by hand.

part b.

remarks and explorations

Indeed, MAPLE gets lots of zeros for other curves, too, due to
mistakes with branch-cuts.... In this example the argument of the
second log clearly winds around zero.... and the fundemantal
theorem fails ... think about it --- how could MAPLE possibly
tell --- human intervention is indeed needed.

> restart;
zt:=1+(1/2)*exp(I*t);
assume(t,real);
assume(r,real);
int3:=simplify(1/conjugate(zt)*diff(zt,t));
int(int3,t);
`wrong answer`=int(int3,t=0..2*Pi);

I am a very wary soul -- and thus do everything nontrivial by hand.
Clearly the integrand is not analytic as it does not satisfy the CRE

except at a few points.
Green's theorem effectively amounts to integrating the defects in the
CRE over the enclosed region -- recall:

> restart;

Green's theorem says that with the suitable interpretation of the
integrals over a region and its boundary

> Int(P,x)+Int(Q,y)=
Int(Int(Q[x]-P[y],x),y);

Applying this to the real and imgainary part of f(z)dz separately

> (u+I*v)*(dx+I*dy)=evalc((u+I*v)*(dx+I*dy));

yields with P = u and Q = - v

> Int(u,x)-Int(v,y)=
- Int(Int(v[x]+u[y],x),y);

and with P = v and Q = u

> Int(u,x)+Int(v,y)=
Int(Int(u[x]-v[y],x),y);

Note that the integrals may be zero even if the integrand is not.
Indeed, in this particular example the integrands have lots of
symmetry, and hence the integrals over many "symmetric"
regions are zero!
Take a closer look at and .

> restart;
w:=evalc(subs(z=x+I*y,1/conjugate(z)));

> assume(x,real);
assume(y,real);
u:=Re(w);
v:=Im(w);

> simplify(diff(u,x)-diff(v,y));
diff(u,y)+diff(v,x);

Actually -- it is not that easy for a region to be such that the integrals
of BOTH functions vanish -- the latter is e.g. odd in both x and y, and
hence the integral over any region that is symmtric about any of the
coordinate axes is zero. The first is antisymmrtic in x and y, and hence
the integral over any region that is symmertic about the line y=x vanishes.

Yet due to the branch-cut troubles MAPLE gives many more zero
results than for these special kinds of curves. Learning from this, we
should have lots of respect for branch-cuts, be very skeptical about
any results by the CAS, andlook very carefully at any intermediate
results -- in the above examples the occurrences of the logarithms
in the antiderivatives gave away the trouble.

>

Problem 2

For a start draw a picture

> restart;
with(plots):
curves:=
plot([cos(t),1+sin(t),t=0..2*Pi],
thickness=3,color=blue),
plot([cos(t),-1+sin(t),t=0..2*Pi],
thickness=3,color=green),
plot([5*cos(t),5*sin(t),t=0..2*Pi],
thickness=3,color=red):
display([curves],scaling=constrained,
axes=normal,tickmarks=[3,3]);

>

part a.

The function

> w:=sin(z)/(z^2+1);

is analytic everywhere except at the roots of the denominator,
i.e. everywhere except at

> solve(denom(w)=0,z);

Hence the circle C may be continuously defomed to the union of the
circles C1 and C2 where each intermediate curve lies inside the domain
of analyticity of w=f(z).
The animaiton is fun.

> with(plottools):

> disks:=
disk([0,1],0.2,color=black),
disk([0,-1],0.2,color=black),
disk([0,1],1,color=white),
disk([0,-1],1,color=white),
disk([0,0],5,color=COLOR(RGB,1,0.95,0.9)):

> N:=12:
homo:=k->display([
plot([(1-k/N)*5*cos(t)+(k/N)*cos(2*t+Pi/2),
(1-k/N)*5*sin(t)+(k/N)*(-1+sin(2*t+Pi/2)),
t=Pi..2*Pi],
color=COLOR(RGB,1-k/N,k/N,0),
thickness=4),
plot([(1-k/N)*5*cos(t)+(k/N)*cos(2*t-Pi/2),
(1-k/N)*5*sin(t)+(k/N)*(1+sin(2*t-Pi/2)),
t=0..Pi],
color=COLOR(RGB,1-k/N,0,k/N),
thickness=4)]):

> display([seq(display([homo(k), disks,curves]),k=0..N),
seq(display([homo(N-k),disks,curves]),k=1..N)],
insequence=true,axes=normal,tickmarks=[3,3],
scaling=constrained,
title=`Homotopy animation - play me!`);

part b.

The function w=f(z) is analytic throughout the region bounded by C and the
reversals of C1 and C2 (shaded pink above) -- and hence the integral of f(z)
over C equals the sum of the integrals of f(z) over C1 and C2.

>

Factor the denominator

> fn:=factor(denom(w),I);

and rewrite the integrands suitably as

> w=g[1](z)/op(2,fn);
w=g[2](z)/(fn/op(2,fn));

where

> g[1](z):=simplify(numer(w)/fn*op(2,fn));
g[2](z):=simplify(numer(w)/fn*op(1,fn));

are analytic throughout one of the two small disks, respectively.

Using Cauchy's integral formula yields

> z1:=solve(op(2,fn)=0,z);
z2:=solve(op(1,fn)=0,z);

> J[C[1]]:=2*Pi*I*subs(z=z1,g[1](z));
J[C[2]]:=2*Pi*I*subs(z=z2,g[2](z));

and hence the original integral equals

> J[C]=J[C[1]]+J[C[2]];

Problem 3

part a.

Assuming that f(z) is analytic on the (simply connected) closed disk with center 0
and radius r>0, Cauchy's Integral Formula asserts that the value of the derivative
of f at the origin equals (1/2 I) times the contour integral of f(z)/(z-0) along the
circle with radius r and center 0.
Paramterizing the cricle

> zt:=0+r*exp(I*theta);
trange:=theta=0..2*Pi;
dzt:=diff(zt,theta);

and substituting it into the integrand yields

> Int(f(z)/(z-0)^2,z)=
int(subs(z=zt,f(z)/(z-0)^2)*dzt,trange);

>

The desired form is obtained by observing that r is constant with respect to and
hence may be moved outside the integrand, and using negative exponents to move
the exponential from the denominator to the numerator.

>

part b.

Here we write dfdz for f '.

By Cauchy's integral formula

> assume(r>0);
abs(dfdz(0)) = abs(1/2/Pi/I/r*Int(I*exp(-I*theta)*f(r*exp(I*theta)),theta=0..2*Pi));

upon moving the absolute values inside the integral

> r:='r':
assume(theta,real):
abs(dfdz(0)) <= 1/2/Pi/r*Int(abs(I*exp(-I*theta)*f(r*exp(I*theta))),theta=0..2*Pi);

Now assume that

> abs(f(z)) < 5*r;

for all points z on some circle { z : | z - 0 | = r } (i.e. for some r > 0 ).
This yields the estimate

> abs(dfdz(0)) < 1/2/Pi/r*Int(5*r,theta=0..2*Pi);

> abs(dfdz(0)) < 1/2/Pi/r*int(5*r,theta=0..2*Pi);

Which contradicts

> dfdz(0)=5*I;

Hence on every circle with center 0 and any radius r > 0 there must be a point
z such that

> abs(f(z))>=5*r;

bonus

This does not imply anything for f(0).
Indeed, if f(z) was replaced by ( f(z) + C ) for any complex constant C, then on
one side f ( 0 ) could be made to have any value, while on the other side f '(0 ) = 5 i

and the integral remain completely unaffected:
Note that in the integral
Int(f(z)/(z-0)^2,z)=
int(subs(z=zt,f(z)/(z-0)^2)*dzt,trange);
one of the above are affected if any constant f

> Int((f(z)+C)/(z-0)^2,z)=Int(f(z)/(z-0)^2,z);

since

> Int(C/z^2,z)=0;

as is easily verified e.g. by direct computation

> zt:=r*exp(I*t);
Int(subs(z=zt,C/z^2)*diff(zt,t),t=0..2*Pi)=
int(subs(z=zt,C/z^2)*diff(zt,t),t=0..2*Pi);

>

Problem 4

No sample answer available.
Students are encouraged to share their responses.